settings.gradle

pluginManagement {
    repositories {
        google()
        gradlePluginPortal()
        maven { url "https://storage.googleapis.com/r8-releases/raw"}
    }
    resolutionStrategy {
        eachPlugin {
            // https://github.com/google/play-services-plugins/issues/223
            if (requested.id.id == "com.google.android.gms.oss-licenses-plugin") {
                useModule("com.google.android.gms:oss-licenses-plugin:${requested.version}")
            }
        }
    }
    buildscript {
        dependencies {
            // https://issuetracker.google.com/issues/262661471
            classpath("com.android.tools:r8:4.0.47")
        }
    }
}

// https://docs.gradle.com/enterprise/gradle-plugin/
plugins {
    id "com.gradle.enterprise" version "3.12"
}

gradleEnterprise {
    buildScan {
        termsOfServiceUrl = "https://gradle.com/terms-of-service"
        termsOfServiceAgree = "yes"
        publishAlways()
    }
}

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
        maven { url 'https://jitpack.io' }
    }
}

enableFeaturePreview("STABLE_CONFIGURATION_CACHE")
enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")

include ':iconloaderlib'
project(':iconloaderlib').projectDir = new File(rootDir, 'platform_frameworks_libs_systemui/iconloaderlib')

include ':searchuilib'
project(':searchuilib').projectDir = new File(rootDir, 'platform_frameworks_libs_systemui/searchuilib')

include ':SystemUIShared'
include ':CompatLib'
include ':CompatLibVR'
include ':CompatLibVS'
include ':hidden-api'