Vim9: Class/Object member variable access control

[yegappan]

Functions outside of a Vim9 class/object can have read-only access or a read-write access or no access
to a class/object member variable. This is described in https://vimhelp.org/vim9class.txt.html.

The following sample code shows how to declare member variables with these different access controls:

vim9script
class A
    # object member: read-only access
    this.val1 = 10
    # object member: read/write access
    public this.val2 = 20
    # object member: private (no access)
    this._val3 = 30

    # class member: read-only access
    static val4 = 40
    # class member: read/write access
    public static val5 = 50
    # class member: private (no access)
    static _val6 = 60
endclass

This page is created to track the different ways these member variables can be accessed and whether they
are tested and verified to work properly. The following cases are tested with the changes in the PR #12978.

Access from script level:

vim9script
class A
    this.ro_obj_var = 10
    public this.rw_obj_var = 20
    this._priv_obj_var = 30

    static ro_class_var = 40
    public static rw_class_var = 50
    static _priv_class_var = 60
endclass

var a = A.new()
echo a.ro_obj_var		# Works
a.ro_obj_var = 0		# Fails with E1335 (expected)
echo a.rw_obj_var		# Works
a.rw_obj_var = 0		# Works
echo a._priv_obj_var		# Fails with E1333 (expected)
a._priv_obj_var = 0		# Fails with E1333 (expected)

echo A.ro_class_var		# Works
A.ro_class_var = 0		# Fails with E1335 (expected)
echo A.rw_class_var		# Works
A.rw_class_var = 0		# Works
echo A._priv_class_var		# Fails with E1333 (expected)
A._priv_class_var = 0		# Fails with E1333 (expected)

Access from a def function:

vim9script
class A
    this.ro_obj_var = 10
    public this.rw_obj_var = 20
    this._priv_obj_var = 30

    static ro_class_var = 40
    public static rw_class_var = 50
    static _priv_class_var = 60
endclass

def T()
    var a = A.new()
    echo a.ro_obj_var		# Works
    a.ro_obj_var = 0		# Fails with E1335 (expected)
    echo a.rw_obj_var		# Works
    a.rw_obj_var = 0		# Works
    echo a._priv_obj_var	# Fails with E1333 (expected)
    a._priv_obj_var = 0		# Fails with E1333 (expected)
    
    echo A.ro_class_var		# Works
    A.ro_class_var = 0		# Fails with E1089 (BUG)
    echo A.rw_class_var		# Works
    A.rw_class_var = 0		# Fails with E1089 (BUG)
    echo A._priv_class_var	# Works (BUG)
    A._priv_class_var = 0	# Fails with E1089 (BUG)
enddef
T()

Access from a method in the class:

vim9script
class A
    this.ro_obj_var = 10
    public this.rw_obj_var = 20
    this._priv_obj_var = 30

    static ro_class_var = 40
    public static rw_class_var = 50
    static _priv_class_var = 60

    def Foo()
	echo this.ro_obj_var	# Works
	this.ro_obj_var = 0	# Works
	echo this.rw_obj_var	# Works
	this.rw_obj_var = 0	# Works
	echo this._priv_obj_var	# Works
	this._priv_obj_var = 0	# Works
	
	echo ro_class_var	# Works
	ro_class_var = 0	# Works
	echo rw_class_var	# Works
	rw_class_var = 0	# Works
	echo _priv_class_var	# Works
	_priv_class_var = 0	# Works

	echo A.ro_class_var	# Works
	A.ro_class_var = 0	# Fails with E1089 (BUG)
	echo A.rw_class_var	# Works
	A.rw_class_var = 0	# Fails with E1089 (BUG)
	echo A._priv_class_var	# Works
	A._priv_class_var = 0	# Fails with E1089 (BUG)
    enddef
endclass

var a = A.new()
a.Foo()

Access from a method in a different class:

vim9script
class A
    this.ro_obj_var = 10
    public this.rw_obj_var = 20
    this._priv_obj_var = 30

    static ro_class_var = 40
    public static rw_class_var = 50
    static _priv_class_var = 60
endclass

class B
    def Foo()
	var a = A.new()
	echo a.ro_obj_var	# Works
	a.ro_obj_var = 0	# Fails with E46 (expected)
	echo a.rw_obj_var	# Works
	a.rw_obj_var = 0	# Works
	echo a._priv_obj_var	# Fails with E1333 (expected)
	a._priv_obj_var = 0	# Fails with E1333 (expected)
	
	echo A.ro_class_var	# Works
	A.ro_class_var = 0	# Fails with E1089 (BUG)
	echo A.rw_class_var	# Works
	A.rw_class_var = 0	# Fails with E1089 (BUG)
	echo A._priv_class_var	# Works (BUG)
	A._priv_class_var = 0	# Fails with E1089 (BUG)
    enddef
endclass

var b = B.new()
b.Foo()

Access from child class extending a class:

vim9script
class A
    this.ro_obj_var = 10
    public this.rw_obj_var = 20
    this._priv_obj_var = 30

    static ro_class_var = 40
    public static rw_class_var = 50
    static _priv_class_var = 60
endclass

class B extends A
    def Foo()
	echo this.ro_obj_var	# Works
	this.ro_obj_var = 0	# Works
	echo this.rw_obj_var	# Works
	this.rw_obj_var = 0	# Works
	echo this._priv_obj_var	# Works
	this._priv_obj_var = 0	# Works
	
	echo ro_class_var	# Works
	ro_class_var = 0	# Works
	echo rw_class_var	# Works
	rw_class_var = 0	# Works
	echo _priv_class_var	# Works
	_priv_class_var = 0	# Works

	echo A.ro_class_var	# Works
	A.ro_class_var = 0	# Fails with E1089 (BUG)
	echo A.rw_class_var	# Works
	A.rw_class_var = 0	# Fails with E1089 (BUG)
	echo A._priv_class_var	# Works
	A._priv_class_var = 0	# Fails with E1089 (BUG)
    enddef
endclass

var b = B.new()
b.Foo()

Access from a class implementing an interface:

vim9script
interface A
    this.ro_obj_var: number
    public this.rw_obj_var: number
    this._priv_obj_var: number

    static ro_class_var: number
    public static rw_class_var: number
    static _priv_class_var: number
endinterface

class B implements A
    this.ro_obj_var = 10
    public this.rw_obj_var = 20
    this._priv_obj_var = 30

    static ro_class_var = 40
    public static rw_class_var = 50
    static _priv_class_var = 60

    def Foo()
	echo this.ro_obj_var	# Works
	this.ro_obj_var = 0	# Works
	echo this.rw_obj_var	# Works
	this.rw_obj_var = 0	# Works
	echo this._priv_obj_var	# Works
	this._priv_obj_var = 0	# Works
	
	echo ro_class_var	# Works
	ro_class_var = 0	# Works
	echo rw_class_var	# Works
	rw_class_var = 0	# Works
	echo _priv_class_var	# Works
	_priv_class_var = 0	# Works

	echo A.ro_class_var	# Works
	A.ro_class_var = 0	# Fails with E1089 (BUG)
	echo A.rw_class_var	# Works
	A.rw_class_var = 0	# Fails with E1089 (BUG)
	echo A._priv_class_var	# Works
	A._priv_class_var = 0	# Fails with E1089 (BUG)
    enddef
endclass

var b = B.new()
b.Foo()

Note: The last test crashes Vim.

[stefanos82]

If I may ask, what was the reasoning behind the use of underscore for private member variables and not the use of private keyword?

Was it a matter of aesthetics or inspired by Python pseudo-privacy mechanism?

[yegappan]

The rationale for using underscore in private class/object member variable names is described in the section titled "Making object members private with an underscore" in https://vimhelp.org/vim9class.txt.html#_rationale

[stefanos82]

For some reason the use of underscore from an aesthetic point of view does not feel "right", but if it works... 😒

Something like the following examples make it more obvious to my tired eyes that they mean private member:

# Version 1

vim9script
class A
    this::val = 10 # "::" for private members
endclass

var a = A.new()
echo a::val	# Fails with E1333 (expected)
a::val = 20	# Fails with E1333 (expected)

# Version 2

vim9script
class A
    this.$val = 10 # "$" for private members
endclass

var a = A.new()
echo a.$val	# Fails with E1333 (expected)
a.$val = 20	# Fails with E1333 (expected)

Maybe it's not clear with the aforementioned examples, but with the use of private methods inside classes, it makes it clearer:

# Original before from https://vimhelp.org/vim9class.txt.html#_rationale

class SomeClass
	def _Foo(): number
	  return 10
	enddef
	def Bar(): number
	  return this._Foo()
	enddef
endclass

# Version 1
class SomeClass
	def this::Foo(): number
	  return 10
	enddef
	def Bar(): number
	  return this::Foo()
	enddef
endclass

# Version 2
class SomeClass
	def $Foo(): number
	  return 10
	enddef
	def Bar(): number
	  return this.$Foo()
	enddef
endclass

[chrisbra]

whether we use _ or :: or $ for private members seems like bike-shedding. And that decision has already been made 🤷

[stefanos82]

Oh well... 🤷

[errael]

@yegappan Can you suggest something or related somethings that you'd expect to take less than a day to fix?

[errael]

Instead of preventing the usage of static members in interfaces, we should fix this crash.

I agree. But since it looks like a development task, not just a bug fix, preventing it is a fallback while the bugs are rooted out. (hope I'm wrong).

[yegappan]

After going through your analysis and the code, it now makes sense to give an error when an interface member variable is referenced using the interface name. A member variable in an interface cannot be initialized. So it doesn't makes sense to allow read or write to this variable.
Can you create a PR for this?

[errael]

So it doesn't makes sense to allow read or write to this variable.
Can you create a PR for this?

(I'm still not entirely comfortable with how statics works, but I understand now)

What sounds like a good error message? How about

Cannot directly access static through interface.

or something like

Only access a static through a class, never an interface

Just thought of something else, and I'm still confused. What about

vim9script

interface I
    public static s_var: number
endinterface
class C implements I
    public static s_var = 3
endclass

def F(i: I)
    var x = i.s_var
enddef
var c = C.new()
F(c)

If that doesn't work, then interfaces don't work.

[errael]

BTW, the compilation error is

E1326: Member not found on object "I": s_var

for

def F(i: I)
    var x = i.s_var
enddef

[errael]

I may be getting back to the "disallow statics in interfaces in this release" point of view.

[errael]

I was asked to look at the crash; I'll finish what I'm doing, trying to track down the specifics of the crash, but maybe not a solution. He had something to look at after the crash; so I'll probably do that. As far as I'm concerned there should be a central figure coordinating, to prevent interference.

I do wonder why you felt it necessary to post that in the middle of the thread about the crash, rather than starting a separate thread. It's rude.

[mg979]

Sorry I didn't mean to be rude, just thought that starting from the hardest problem to solve maybe wasn't ideal. It was just a suggestion.

[errael]

just a suggestion.

Which is OK with me. But a separate thread seems more appropriate.

[errael]

A member variable in an interface cannot be initialized.
So it doesn't makes sense to allow read or write to this variable.
Can you create a PR for this?

@yegappan #13007

But until the issue of def F(i: I) is resolved, it might not make sense to apply this. Except as a last ditch effort to avoid a crash.

[yegappan]

The member access control issues discussed above are all addressed in the latest version of Vim.

[errael]

A member variable in an interface cannot be initialized.
So it doesn't makes sense to allow read or write to this variable.
Can you create a PR for this?

#13007 prevents direct access to interface statics. It also allows a :def outside of class to read statics.