build.gradle

plugins {

  id 'groovy'
  id 'maven'
  id 'eclipse'
  id 'idea'
  id 'project-report'

  id "net.saliman.cobertura" version "2.2.5"
  id "com.github.hierynomus.license" version "0.11.0"
  id "org.ajoberstar.github-pages" version "0.10.0"
  id "org.asciidoctor.gradle.asciidoctor" version "1.5.0"

}

group = 'com.aestasit.infrastructure.sshoogr'
version = '0.9.19-SNAPSHOT'

apply from: 'repos.gradle'
apply from: 'sonar.gradle'
apply from: 'docs.gradle'

dependencies {
  compile "org.codehaus.groovy:groovy-all:${groovyVersion}"
  compile "org.slf4j:slf4j-api:${slf4jVersion}"
  compile "org.slf4j:jcl-over-slf4j:${slf4jVersion}"
  compile "ch.qos.logback:logback-classic:${logbackVersion}"
  compile "commons-io:commons-io:${commonsIOVersion}"
  compile "commons-codec:commons-codec:${commonsCodecVersion}"
  compile "com.jcraft:jsch:${jschVersion}"
  testCompile "junit:junit:${junitVersion}"
  testCompile "com.aestasit.infrastructure.mock:groovy-sshd-mock:0.3"
}

sourceSets {
  integrationTest {
    compileClasspath += main.output + test.output
    runtimeClasspath += main.output + test.output
  }
}

configurations {
  all*.exclude group: 'commons-logging'
  all*.exclude group: 'log4j'
  all*.exclude module: 'slf4j-simple'
  integrationTestCompile.extendsFrom testCompile
  integrationTestRuntime.extendsFrom testRuntime
}

task wrapper(type: Wrapper) {
  gradleVersion = '2.1'
}

task integration(type: Test) {
  description = "Run integration tests (located in src/integrationTest/groovy)."
  testClassesDir = project.sourceSets.integrationTest.output.classesDir
  classpath = project.sourceSets.integrationTest.runtimeClasspath
}

idea {
  module {
    testSourceDirs += file('src/integrationTest/groovy')
  }
}

license {
  header rootProject.file('HEADER')
}