build.gradle

buildscript {
    ext {
        version = '2.0.0'
        versionCode = 28
        minSdkVersion = 14
        targetSdkVersion = 27
        compileSdkVersion = 27

        gradleVersion = '4.4.1'

        androidPluginVersion = '3.0.1'
        gradleVersionsPluginVersion = '0.17.0'

        supportLibraryVersion = '27.0.2'
        glideVersion = '3.8.0'

        deps = [
                androidPlugin       : "com.android.tools.build:gradle:$androidPluginVersion",
                gradleVersionsPlugin: "com.github.ben-manes:gradle-versions-plugin:$gradleVersionsPluginVersion",

                supportAppCompat    : "com.android.support:appcompat-v7:$supportLibraryVersion",
                supportDesign       : "com.android.support:design:$supportLibraryVersion",

                glide               : "com.github.bumptech.glide:glide:$glideVersion",
        ]
    }

    repositories {
        jcenter()
        google()
    }

    dependencies {
        classpath deps.androidPlugin
        classpath deps.gradleVersionsPlugin
    }
}

apply plugin: 'com.github.ben-manes.versions'

allprojects {
    version = rootProject.ext.version

    repositories {
        jcenter()
        google()
        maven { url "https://jitpack.io" }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

task wrapper(type: Wrapper) {
    gradleVersion = project.ext.gradleVersion
}

@SuppressWarnings("GroovyUnusedDeclaration")
static boolean isCI() {
    Object isCI = System.getenv('CI')

    return isCI != null && isCI.toBoolean()
}