nextflow.config

manifest {
    mainScript = 'CoVpipe2.nf'
    name = 'CoVpipe2'
    nextflowVersion = '!>=22.10.1'
}

params {
    cores = 4
    max_cores = 12 //Runtime.runtime.availableProcessors()
    memory = '12'

    help = false
    profile = false
    workdir = false

    // input

    // reads
    fastq = ''
    list = false
    mode = 'paired'
    run_id = ''

    // reference
    reference = 'sars-cov-2' // currently only 'sars-cov-2'
    ref_genome = false // e.g. 'data/reference_SARS-CoV2/NC_045512.2.fasta'
    ref_annotation = false // e.g. 'data/reference_SARS-CoV2/NC_045512.2.gff3'

    // adapter & read trimming
    adapter = false // e.g. 'data/adapters/NexteraTransposase.fasta'
    fastp_additional_parameters = '--qualified_quality_phred 20 --length_required 50'
    
    // kraken
    kraken = false
    kraken_db_custom = ''
    taxid = '2697049'

    // lcs
    read_linage = false
    lcs_ucsc_version = 'predefined' // e.g. '2022-05-01' marker-table date
    lcs_ucsc_predefined = '2022-05-15'
    lcs_ucsc_update = false // update marker table, overrides lcs_ucsc_version
    lcs_ucsc_downsampling = 10000 // 'None' to turn off
    lcs_variant_groups = 'default' // 'default' to use file from repo; custom variant groups table for marker-table update
    lcs_cutoff = 0.03 // for plotting

    isize_filter = false

    // amplicon primer clipping
    primer_bed = false
    primer_bedpe = false
    primer_version = false

    bamclipper_additional_parameters = false

    // variant calling with freebayes
    vcount = 10 
    frac = 0.1
    cov = 20

    // vcf with variants of interest
    vois = false

    // variant hard filtering
    var_mqm = 40
    var_sap = false // disabled
    var_qual = 10

    // consensus generation
    cns_min_cov = 20
    cns_gt_adjust = 0.9
    cns_indel_filter = 0.6
    
    // consensus qc
    seq_threshold = 0.90
    n_threshold = 0.05

    // update settings and default container
    update = false

    pangolin_docker_default = 'rkimf1/pangolin:4.3-1.25.1--380d5e9'
    nextclade_docker_default = 'rkimf1/nextclade3:3.3.1--c7323e6'
    pangolin_conda_default = 'bioconda::pangolin=4.3 bioconda::pangolin-data=1.25.1'
    nextclade_conda_default = 'bioconda::nextclade=3.3.1'
    nextclade_dataset_name = 'sars-cov-2'
    nextclade_dataset_tag = '2024-02-16--04-00-32Z'

    // output folder structure
    output = 'results'
    reference_dir = '00-Reference'
    read_dir = '01-Read-QC'
    mapping_dir = '02-Mapping'
    variant_calling_dir = '03-Variant-Calling'
    consensus_dir = '04-Consensus'
    linage_dir = '05-Linages_Mutations'
    rki_dir = '06-RKI-summary'
    report_dir = 'Report'
    runinfo_dir = 'X.Pipeline-Runinfo'

    // location for engines' cache
    singularity_cache_dir = 'singularity'
    conda_cache_dir = 'conda'

    // location for autodownload data like databases
    databases = 'nextflow-autodownload-databases'

    // softlink results instead of copying
    publish_dir_mode = 'copy' // use 'symlink' to just link the results

    cloudProcess = false
}

// runinfo
def trace_timestamp = new java.util.Date().format( 'yyyy-MM-dd_HH-mm-ss')
timeline {
  enabled = true
  file = "${params.output}/${params.runinfo_dir}/execution_timeline_${trace_timestamp}.html"
}

report {
  enabled = true
  file = "${params.output}/${params.runinfo_dir}/execution_report_${trace_timestamp}.html"
}

profiles {
    // executors
    local {
        executor {
            name = "local"
            cpus = params.max_cores
            memory = params.memory
        }
        params.cloudProcess = false
        includeConfig 'configs/local.config'
    }

    slurm {
        executor {
            name = "slurm"
            queueSize = 100
            // exitReadTimeout = "360 sec"
            // submitRateLimit = '1 / 2 s'
            // pollInterval = '30 sec'
        }
        process.cache = "lenient"
        includeConfig 'configs/nodes.config'
    }

    // engines
    conda { 
        conda {
            enabled = true
            cacheDir = params.conda_cache_dir
        }
        includeConfig 'configs/conda.config'
    }
    mamba { 
        conda {
            enabled = true
            useMamba = true
            cacheDir = params.conda_cache_dir
        }
        includeConfig 'configs/conda.config'
    }

    docker {
        docker { enabled = true }
        includeConfig 'configs/container.config'
    }

    singularity {
        singularity { 
                enabled = true
                autoMounts = true
                cacheDir = params.singularity_cache_dir
                envWhitelist = "HTTPS_PROXY,HTTP_PROXY,http_proxy,https_proxy,FTP_PROXY,ftp_proxy"
        }
        includeConfig 'configs/container.config'
    }

    // pre-merged
    standard { 
        executor {
                name = "local"
               	cpus = params.max_cores
        }
        conda {
            enabled = true
            cacheDir = params.conda_cache_dir
        }
        params.cloudProcess = false
        includeConfig 'configs/local.config'
        includeConfig 'configs/conda.config'
    }

    // test
    test {
        params.fastq          = "$baseDir/tests/amplicon_artic_v1_samplesheet.csv"
        params.list           = true
        params.adapter        = "$baseDir/data/adapters/NexteraTransposase.fasta"
        params.primer_version = 'V1'
        params.frac           = 0.2
    }

    // no config for stub runs
    stub {
        executor {
            name = "local"
            cpus = params.max_cores
        }
    }

    // only load cluster config (without executor) 
    cluster {
        params.cloudProcess = true
        includeConfig 'configs/nodes.config'
    }
}