# flake.nix
{
  inputs = {
    dream2nix.url = "github:nix-community/dream2nix?rev=44d41411686bc798876bd6d9f36a4c1143138d85";
    nixpkgs.follows = "dream2nix/nixpkgs";
  };

  outputs =
    {
      self,
      dream2nix,
      nixpkgs,
    }:
    let
      eachSystem = nixpkgs.lib.genAttrs [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];
    in
    {
      packages = eachSystem (system: {
        default = dream2nix.lib.evalModules {
          packageSets.nixpkgs = nixpkgs.legacyPackages.${system};
          modules = [
            ./package.nix
            {
              paths.projectRoot = ./.;
              paths.projectRootFile = "flake.nix";
              paths.package = ./.;
            }
          ];
        };
      });
      devShells = eachSystem (system: {
        default =
          let
            pkgs = nixpkgs.legacyPackages.${system};
            myPkg = self.packages.${system}.default;
          in
          pkgs.mkShell {
            inputsFrom = [ myPkg.devShell ];
          };
      });
    };
}

# package.nix

{
  config,
  lib,
  dream2nix,
  ...
}:

let
  pyproject = lib.importTOML (config.mkDerivation.src + /pyproject.toml);
in
{
  imports = [
    dream2nix.modules.dream2nix.pip
  ];

  deps =
    { nixpkgs, ... }:
    {
      python = nixpkgs.python310;
      tbb = nixpkgs.tbb_2021_11;
      inherit (nixpkgs)
        atk
        cairo
        cups
        dbus
        fetchFromGitHub
        fontconfig
        freetype
        gst_all_1
        gtk3
        krb5
        libdrm
        libxkbcommon
        pango
        pcsclite
        qt6
        wayland
        xorg
        ;
    };

  inherit (pyproject.project) name version;

  mkDerivation = {
    src = lib.cleanSourceWith {
      src = lib.cleanSource ./.;
      filter =
        name: type:
        !(builtins.any (x: x) [
          (lib.hasSuffix ".nix" name)
          (lib.hasPrefix "." (builtins.baseNameOf name))
          (lib.hasSuffix "flake.lock" name)
        ]);
    };
  };

  buildPythonPackage = {
    pyproject = true;
    pythonImportsCheck = [ "my_tool" ];
  };

  pip = {
    pipVersion = "24.3.1";
    requirementsList = pyproject.build-system.requires or [ ] ++ pyproject.project.dependencies;
    flattenDependencies = true;
    overrides = {
      pyside6-essentials = {
        mkDerivation.buildInputs = with config.deps; [
          atk
          cairo
          cups
          dbus
          fontconfig
          freetype
          gtk3
          krb5
          libdrm
          libxkbcommon
          pango
          qt6.qt3d
          qt6.qtpositioning
          qt6.qtscxml
          qt6.qtvirtualkeyboard
          qt6.qtwebengine
          wayland
          xorg.libxcb
        ];
        env = {
          dontWrapQtApps = true;
          autoPatchelfIgnoreMissingDeps = [ "libmysqlclient.so*" ];
        };
      };
      pyside6-addons = {
        mkDerivation.buildInputs = with config.deps; [
          gst_all_1.gst-plugins-base
          gst_all_1.gstreamer
          pcsclite
          qt6.qtmultimedia
        ];
        env = {
          dontWrapQtApps = true;
        };
      };
    };
  };
}