Issue displaying the Dialog

[minterciso]

Hello, I'm trying to display the sample Dialog with the following code (after a time ends):

func _on_timer_end_animation_timeout():
	$TimerEndAnimation.stop()
	player.set_camera()
	DialogueManager.show_example_dialogue_balloon(load("res://media/dialogs/intro.dialogue"), "intro_start")

However, when I get to that point, it basically breaks with the error Cannot call method 'add_child' on a null value.. The issue happens on this part of the dialogue_manager.gd:

func show_example_dialogue_balloon(resource: DialogueResource, title: String = "", extra_game_states: Array = []) -> void:
	var ExampleBalloonScene = load("res://addons/dialogue_manager/example_balloon/example_balloon.tscn")
	var SmallExampleBalloonScene = load("res://addons/dialogue_manager/example_balloon/small_example_balloon.tscn")

	var is_small_window: bool = ProjectSettings.get_setting("display/window/size/viewport_width") < 400
	var balloon: Node = (SmallExampleBalloonScene if is_small_window else ExampleBalloonScene).instantiate()
	get_tree().current_scene.add_child(balloon)
	balloon.start(resource, title, extra_game_states)

On the get_tree().current_scene.add_child(balloon).

Was there anything else I had to do? I don't believe this is the dialog script I created, since I can use it on the sample scene.

Thank you for your help.

[nathanhoad]

Are you using a custom MainLoop? I'm not sure how current_scene could be null.

[minterciso]

No, I'm using a scene loader singleton for loading the schene:

func load_level_scene(current_scene: Node, level_scene_path: String):
	# add the loading scene to the root tree
	var loading_scene_instance = loading_scene.instantiate()
	get_tree().get_root().call_deferred('add_child', loading_scene_instance)
	
	# Find the target scene on the system
	var err = ResourceLoader.load_threaded_request(level_scene_path)
	# Check for errors:
	if err != OK:
		print('there was an error getting the scene:'+error_string(err))
		return
	
	# Free the current scene
	current_scene.queue_free()
	
	# At least show a quick loading screen
	await get_tree().create_timer(0.5).timeout
	
	# Get the percentage
	var percentage = []
	while true:
		var t_status = ResourceLoader.load_threaded_get_status(level_scene_path, percentage)
		if t_status == 0:
			print('invalid resource')
		elif t_status == 1:
			loading_scene_instance.update_percentage(percentage[0])
		elif t_status == 2:
			print('failed')
		elif t_status == 3:
			loading_scene_instance.update_percentage(percentage[0]) # Update with 100%
			break
	# add the scene loaded on the tree
	var new_scene = ResourceLoader.load_threaded_get(level_scene_path)
	var instantiated_scene = new_scene.instantiate()
	get_tree().get_root().call_deferred('add_child', instantiated_scene)
	# Helpers
	var player = Globals.current_player
	var hud = Globals.hud
	if player == null:
		player = load('res://scenes/characters/space_marine/space_marine.tscn').instantiate()
	# Put the player on the start position (and on the level)
	instantiated_scene.add_child(player)
	player.position = instantiated_scene.get_start_position()
	# Create the hud and add it
	if hud == null:
		hud = hud_scene.instantiate()
	instantiated_scene.add_child(hud)
	# Connect the player to the HUD
	player.changed_weapon.connect(hud.switch_weapon)
	player.changed_health.connect(hud.update_health)
	player.changed_bullets.connect(hud.update_weapon_bullets)
	player.changed_score.connect(hud.update_score)
	# Configure the current level
	Globals.current_level = instantiated_scene
	# remove the loading scene
	loading_scene_instance.queue_free()
	# Call the level intro
	if instantiated_scene.has_method('start_intro_animation'):
		instantiated_scene.start_intro_animation()

It loads the scene (level), then stast the method start_intro_animation when it's done, and at the end of the start_intro_animation on the level node I call the show_example_dialogue_balloon from the DialogueManager.

[nathanhoad]

Ah, I see there that the current scene is freed. I've just merged in #327 which should address the issue you're facing.

[minterciso]

I will of course update and test it, but before I do this, can you please explain to me why this is happening? I was under the impression that when I called the get_tree().get_root().call_deferred('add_child', instantiated_scene) I would be adding the instantiated_scene as the current scene on the root, specially because I loaded the "loading scene" and then I removed it, so it should (at least for my poor understanting) consider the scene tree as root->instantiated->everything_else. Am I missing something here?

[nathanhoad]

Usually you'd use get_tree().change_scene_to_file(...) or get_tree().change_scene_to_packed(...) to change scenes. Otherwise Godot doesn't really know which scene is the "current scene".

[minterciso]

Hum, I see.

Thanks, I'll try updating and testing, and a I'll also try changing the load manager to use the change_scene_to_file(), see if it works.