build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
apply plugin: 'com.github.ksoichiro.console.reporter'
def nexusUID = System.getenv("CN_NEXUS_UID") ? System.getenv("CN_NEXUS_UID") : nexusUID
def nexusPWD = System.getenv("CN_NEXUS_PWD") ? System.getenv("CN_NEXUS_PWD") : nexusPWD

def TWITTER_CALLBACK_URI = System.getenv("TWITTER_CALLBACK_URI") ? System.getenv("TWITTER_CALLBACK_URI") : TWITTER_CALLBACK_URI
def TWITTER_SECRET = System.getenv("TWITTER_SECRET") ? System.getenv("TWITTER_SECRET") : TWITTER_SECRET
def TWITTER_API_KEY = System.getenv("TWITTER_API_KEY") ? System.getenv("TWITTER_API_KEY") : TWITTER_API_KEY


System.out.println("------ Run Configuration")
System.out.println(Runtime.runtime.availableProcessors().intdiv(2) ?: 1)
System.out.println("Run Configuration ------")


buildscript {
    ext.kotlin_version = '1.3.50'

    repositories {
        google()
        jcenter()
        mavenCentral()
        maven {
            url 'https://maven.fabric.io/public'
        }
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.5.1'
        classpath 'com.github.ksoichiro:gradle-console-reporter:0.6.2'
        classpath 'org.greenrobot:greendao-gradle-plugin:3.2.2'
        classpath "com.github.triplet.gradle:play-publisher:2.2.1"
        classpath 'de.felixschulze.gradle:gradle-hockeyapp-plugin:3.6'
        classpath 'com.google.gms:google-services:4.3.2'
        classpath "de.mannodermaus.gradle.plugins:android-junit5:1.3.2.0"
        classpath 'io.fabric.tools:gradle:1.26.1'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.jetbrains.kotlin:kotlin-allopen:$kotlin_version"
        classpath 'com.adarshr:gradle-test-logger-plugin:1.7.0'
    }
}

allprojects {
    repositories {
        google()
        jcenter()
        mavenCentral()
        maven { url 'https://jitpack.io' }
        maven {
            url "https://nexus.coinninja.net/repository/maven-releases/"
            credentials {
                username nexusUID
                password nexusPWD
            }
        }

        maven {
            url "https://jitpack.io"
        }

        maven {
            url 'https://maven.google.com/'
        }
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
    }

    tasks.withType(Test) {
        maxParallelForks = Runtime.runtime.availableProcessors().intdiv(2) ?: 1
        forkEvery = 100
        reports.html.enabled = false
        reports.junitXml.enabled = false
    }

    tasks.withType(JavaCompile) {
        options.fork = true
        options.incremental = true
    }

    apply plugin: 'kotlin-allopen'

    allOpen {
        annotations("app.dropbit.annotations.Mockable", "app.coinninja.annotations.Mockable")
    }
}


task clean(type: Delete) {
    delete rootProject.buildDir
}

ext {
    room_version = "2.1.0"

    // App Configuration
    minSdkVersion = 21
    targetSdkVersion = 28
    buildToolsVersion = "29.0.2"
    compileSdkVersion = 28

    // Dependency Versions
    retrofit_version = "2.5.0"
    junit_version = "4.12"
    appcompat_version = "1.1.0-beta01"
    material_version = "1.1.0-alpha10"
    constraintLayout_version = "1.1.3"
    dagger_version = "2.22.1"
    androidx_runner_version = "1.1.1"
    robolectric_version = "4.2"
    espresso_core_version = "3.2.0-beta01"
    //espresso_core_version = "3.2.0-alpha04"
    androidx_fragment_testing_version = "1.2.0-alpha03"
    //androidx_fragment_testing_version = "1.1.0-alpha06"
    expresso_intents_version = "3.1.1"

    // shared vars
    twitterApiKey = TWITTER_API_KEY
    twitterSecret = TWITTER_SECRET
    twitterCallbackUri = TWITTER_CALLBACK_URI
}