adding an option to use include instead of using to avoid precompilation

[thautwarm]

tyjuliacall/tyjuliasetup/__init__.py

Line 230 in 8ff48ed

jnumpy.init_project(__file__)

[thautwarm]

@songjhaha Sysimage-compatible using:

module ImageUsing

if isdefined(Base, :Experimental) && isdefined(Base.Experimental, Symbol("@compiler_options"))
    @eval Base.Experimental.@compiler_options compile=min optimize=0 infer=no
end

exported_names(m::Module) = filter!(x -> Base.isexported(m, x), names(m; all=true, imported=true))

function _eval_export(__module__::Module, x::Any)
    if x isa Symbol
        return getfield(__module__, x)
    elseif x isa Expr
        if x.head == :. && length(x.args) == 2 && x.args[2] isa QuoteNode && x.args[2].value isa Symbol
            v = _eval_export(__module__, x.args[1])
            return getfield(v, x.args[2].value)
        else
            error("invalid export: $x")
        end
    else
        error("invalid export: $x")
    end
end

"""
    `@image_using A.B`
an alternative to using to compat loading packages from custom sysimages.
"""
macro image_using(sections)
    try
        M = _eval_export(Main, sections) :: Module
        ns = exported_names(M)
        block = Expr(:block)
        for n in ns
            if !isdefined(__module__, n)
                push!(block.args, :(const $n = $M.$n))
            end
        end
        esc(block)
    catch
        esc(Meta.parse("using " * string(sections)))
    end
end

end