build.gradle

import org.ajoberstar.grgit.Grgit

apply from: 'config/keystore.gradle'

buildscript {
    repositories {
        gradlePluginPortal()
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.0.1'
        classpath 'org.ajoberstar.grgit:grgit-gradle:4.1.1'
        classpath 'org.jacoco:org.jacoco.core:0.8.7'
    }
}

subprojects {
    repositories {
        google()
        mavenCentral()
    }
}

ext.verifyKeystore()

project.ext {
    minSdkVersion = 16
    compileSdkVersion = 33
    versionID = "0.11.2"
    versionName = """$versionID-skyscanner"""

    try {
        def grgit = Grgit.open(currentDir: project.rootDir)
        versionCode = grgit.log(includes: ['HEAD']).size()
    } catch (Exception ignored) {
        versionCode = 1
    }

    googleVersions = [
        glide                 : '4.12.0',
        material              : '1.3.0',
    ]

    androidXVersions = [
        annotation            : '1.2.0',
        appCompat             : '1.3.0',
        browser               : '1.3.0',
    ]

    okioVersion = '2.10.0'
    jodaVersion = '2.10.10'
}

task showVersion {
    doLast {
        logger.lifecycle("Version ID: " + project.versionID)
        logger.lifecycle("Version Name: " + project.versionName)
        logger.lifecycle("Version Code: " + project.versionCode)
    }
}