How to extract JS links?

[mlen108]

I'm trying to extract a page that uses old school "onlick" to navigate around.

Code I have come up with so far:

LET doc = DOCUMENT('https://nissan.catalogs-parts.com/#{client:1;page:detail;lang:ru;catalog:el;detail:28913bm410}', true)

WAIT_ELEMENT(doc, 'div.panel-group', 5000)

LET items = ELEMENTS(doc, 'div.panel-group table tr td')
FOR itm IN items
  FILTER CONTAINS(itm.innerText,"UK MAKE") == true
  // get next page & extract more links
  // CLICK(itm) ???
  RETURN itm.innerText

Thanks for any tips!

[ziflex]

Hey, that's a pretty good example!
I have created 2 new issues to unblock this.
Currently, if you click an item within the loop - all elements would be disconnected from a page, and on a second iteration, you would get nothing.

EDIT: removed invalid query

[ziflex]

Ok, with new features, here is a working query:

LET url = 'https://nissan.catalogs-parts.com/#{client:1;page:detail;lang:ru;catalog:el;detail:28913bm410}'
LET doc = DOCUMENT(url, true)

LET panelSelector = 'div.panel-group'
LET rowSelector = 'table tr'
LET mainWaitSelector = panelSelector + ' ' + rowSelector

// wait for data
WAIT_ELEMENT(doc, mainWaitSelector)

// gathering rows with accurate CSS selectors
LET rows = (
   FOR accordion IN ELEMENTS(doc, panelSelector)
       FOR row, idx IN ELEMENTS(accordion, rowSelector)
           LET num = idx + 1
           RETURN '#' + accordion.attributes.id + ' ' + rowSelector + ':nth-child('+num+')'

)

LET count = LENGTH(rows)
LET tableSelector = '#modif_table table tbody'

LET results = (
    FOR idx IN 1..count
        FILTER CONTAINS(INNER_TEXT(doc, rows[idx]),  'UK MAKE') == true

        CLICK(doc, rows[idx])

        LET dataRowSelector = tableSelector + ' tr'

        // wait for data
        WAIT_ELEMENT(doc, dataRowSelector)

        LET items = (
            FOR row IN ELEMENTS(doc, dataRowSelector)
                RETURN {
                    body: INNER_TEXT(row, 'td:nth-child(3)'),
                    engine: INNER_TEXT(row, 'td:nth-child(4)')
                }
        )

        // set timeout to 0 to inform Ferret to not wait for navigation event
        NAVIGATE_BACK(doc, 1, 0)

        // wait for data on main page again
        WAIT_ELEMENT(doc, mainWaitSelector)

        RETURN items
)


RETURN FLATTEN(results)

[mlen108]

Wow thank you a lot! I think I would never write it like this... 😸

[ziflex]

Glad that I could help you with this :)