build.gradle

/*
* Copyright (c) 2011 the original author or authors
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
*      http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'maven-publish'
apply plugin: 'signing'
apply plugin: 'idea'

group = 'org.gradlefx'
version = '5.7.0'
ext.packaging = 'jar'

def isDevBuild
def isCiBuild
def isReleaseBuild

def sonatypeRepositoryUrl

//set build variables based on build type (release, continuous integration, development)
if(hasProperty("release")) {
    isReleaseBuild = true
    sonatypeRepositoryUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
} else if (hasProperty("ci")) {
    isCiBuild = true
    version += "-SNAPSHOT"
    sonatypeRepositoryUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
} else {
    isDevBuild = true
}

repositories {
    jcenter()
    mavenCentral()
}

dependencies {
    implementation gradleApi()
    implementation group: 'commons-lang', name: 'commons-lang', version: '2.6'
    implementation group: 'commons-io', name: 'commons-io', version: '2.7'
    implementation group: 'org.codehaus.groovy', name: 'groovy-all', version: '3.0.5'
    testImplementation group: 'org.spockframework', name: 'spock-core', version: '1.3-groovy-2.5'
}

task groovydocJar(type: Jar, dependsOn: groovydoc) {
    getArchiveClassifier().set('javadoc')
    from 'build/docs/groovydoc'
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    getArchiveClassifier().set('sources')
}

artifacts {
    archives jar
    archives groovydocJar
    archives sourcesJar
}

//********* artifact signing *********
if(isReleaseBuild) {
    signing {
        sign configurations.archives
    }
} else {
    task signArchives {
        // do nothing
    }
}

uploadArchives {
    repositories {
        if (isDevBuild) {
            mavenLocal()
        }
        else {
            mavenDeployer {
                if(isReleaseBuild) {
                    beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
                }

                repository(url: sonatypeRepositoryUrl) {
                  authentication(userName: sonatypeUsername, password: sonatypePassword)
                }

                pom.project {
                   name 'GradleFx'
                   packaging 'jar'
                   description 'GradleFx is a Gradle plugin for building Flex and Actionscript applications'
                   url 'http://gradlefx.github.com/'

                   scm {
                       url 'scm:git@github.com:GradleFx/GradleFx.git'
                       connection 'scm:git@github.com:GradleFx/GradleFx.git'
                       developerConnection 'scm:git@github.com:GradleFx/GradleFx.git'
                   }

                   licenses {
                       license {
                           name 'The Apache Software License, Version 2.0'
                           url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                           distribution 'repo'
                       }
                   }

                   developers {
                       developer {
                           id 'yennicktrevels'
                           name 'Yennick Trevels'
                       }
                       developer {
                           id 'stevendick'
                           name 'Steven Dick'
                       }
                   }
               }
            }
        }
    }
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/nekofar/GradleFx")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
                password = project.findProperty("gpr.key") ?: System.getenv("PASSWORD")
            }
        }
    }
    publications {
        gpr(MavenPublication) {
            from(components.java)
        }
    }
}