set_state not working in my macro :(

[fonsp]

The following works great, I use a channel to link values into a magic cell (not useful in this MWE):

Schermopname.2021-11-17.om.21.57.28.mov

# ╔═╡ 6829fa91-9b6d-4c3e-a3d0-141aa381d7ed
boringchannel = Channel(1)

# ╔═╡ 99f62a23-5fb8-438b-87d7-563a0bf07d85
put!(boringchannel, rand())

# ╔═╡ fc3bfd88-8698-40c0-9928-88b49e448b2b
let
	state, set_state = @use_state(rand())

	@use_task([]) do
		try
			while true
				newval = Base.take!(boringchannel)
				@warn "Received new val!!" newval
				set_state(newval)
			end
		catch e
			@error "asdf" exception=(e,catch_backtrace())
		end
	end

	@warn "New state" state

	state, rand()
end

But 💔

when I put this functionality into a macro (@huh), the set_state has no effect:

Schermopname.2021-11-17.om.21.55.04.mov

# ╔═╡ db8e85af-6e6d-4e7e-8ef2-3ff26ddc93d4
coolchannel = Channel(1)

# ╔═╡ 8db1ba73-918c-4c26-a468-8a96078169a7
put!(coolchannel, rand())

# ╔═╡ 5cbed509-3d60-46ef-ba19-220b06377bdb
@huh()

# ╔═╡ b795087f-5e8d-4a09-ae35-9617942a9f4b
macro huh()
	quote
		state, set_state = @use_state(rand())

		@use_task([]) do
			try
				while true
					newval = Base.take!(coolchannel)
					@warn "Received new val!!" newval
					set_state(newval)
				end
			catch e
				@error "asdf" exception=(e,catch_backtrace())
			end
		end

		@warn "New state" state

		state, rand()
	end
end

[dralletje]

So turns out this is because of the way Julia seems to do the macro "hygiene" stuff.
Inside @use_state we also use the name state and set_state, and apparently Julia takes that to mean that it should actually be the same state and set_state variables. So, while gensym-ing everything, it will give these two set_state's (one assigned in @huh() and the other in @use_state) the same exact name.

This is "fine" when you use @use_state yourself, but turns out @use_task also uses @use_state, which will assign to the exact same set_state as your own definition. So, weirdly enough, inside the function you pass to @use_task, set_state refers to the @use_task's set_state! D:

In my testing I found no way to work around it, other than explicitly gensym-ing every variable you use..

I'll open an issue on Julia for this...

[dralletje]

Note the fact that all the variables in the expanded version have the same name, thus they are overriding them :/

Removing the assignment does tip Julia to the fact these are two different variables, but obviously we can't expect people to know what variable they can and can't use >_>

Removing the esc(..) around block changes nothing.
I've seen this a bunch with macros, where adding or removing an esc(..) changes absolutely nothing about the macroexpanded result 🥲

[fonsp]

JuliaLang/julia#43151

[Pangoraw]

As a workaround for the Julia issue I built a small package (Hygienic.jl) that can hygienize the quote returned by the macro:

using Hygienic

julia> @hygienize quote
                       rerun_cell_fn = @give_me_rerun_cell_function()
                       state_ref = @use_ref()
                       set_state = (new) -> begin
                               new_value = if hasmethod(new, Tuple{typeof(new)})
                                       new(state_ref[])
                               else
                                       new
                               end

                               state_ref[] = new_value
                               rerun_cell_fn()
                       end
                       (state_ref[], set_state)
       end    
quote
    #= REPL[5]:2 =#
    var"##rerun_cell_fn#284" = #= REPL[5]:2 =# @give_me_rerun_cell_function()
    #= REPL[5]:3 =#
    var"##state_ref#285" = #= REPL[5]:3 =# @use_ref()
    #= REPL[5]:4 =#
    var"##set_state#288" = (var"##new#286"->begin
                #= REPL[5]:4 =#
                #= REPL[5]:5 =#
                var"##new_value#287" = if hasmethod(var"##new#286", Tuple{typeof(var"##new#286")})
                        #= REPL[5]:6 =#
                        var"##new#286"(var"##state_ref#285"[])
                    else
                        #= REPL[5]:8 =#
                        var"##new#286"
                    end
                #= REPL[5]:11 =#
                var"##state_ref#285"[] = var"##new_value#287"
                #= REPL[5]:12 =#
                var"##rerun_cell_fn#284"()
            end)
    #= REPL[5]:14 =#
    (var"##state_ref#285"[], var"##set_state#288")
end