build.gradle

PluginVersion.updateVersion()
version = PluginVersion.version

buildscript {
    repositories {
        mavenCentral()
        gradlePluginPortal()
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.jetbrains.kotlin:kotlin-serialization:$kotlin_version"
        classpath "com.github.jengelman.gradle.plugins:shadow:$shadow_version"
    }
}

apply plugin: "com.github.johnrengelman.shadow"

allprojects {
    apply plugin: "kotlin"
    apply plugin: "kotlin-kapt"
    apply plugin: "kotlinx-serialization"

    repositories {
        mavenCentral()
        maven { url "https://repo.codemc.org/repository/maven-public" }
    }

    dependencies {
        implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
        implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
        implementation "org.jetbrains.kotlinx:kotlinx-serialization-json-jvm:$kotlinx_serialization_version"
        implementation "com.google.dagger:dagger:$dagger_version"
        implementation "javax.inject:javax.inject:$javax_inject_version"
        implementation "net.benwoodworth.localeconfig:localeconfig-api:$localeconfig_version"
        implementation "org.bstats:bstats-bukkit-lite:$bstats_version"

        kapt "com.google.dagger:dagger-compiler:$dagger_version"

        testImplementation "org.jetbrains.kotlin:kotlin-test:$kotlin_version"
        testImplementation "org.spekframework.spek2:spek-dsl-jvm:$spek_version"
        testRuntimeOnly "org.spekframework.spek2:spek-runner-junit5:$spek_version"
        testRuntimeOnly "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    }

    test {
        useJUnitPlatform {
            includeEngines 'spek2'
        }
    }

    compileKotlin {
        kotlinOptions {
            jvmTarget = java_version
            freeCompilerArgs = ["-Xopt-in=kotlin.RequiresOptIn"]
        }
    }

    compileTestKotlin {
        kotlinOptions {
            jvmTarget = java_version
            freeCompilerArgs = ["-Xopt-in=kotlin.RequiresOptIn"]
        }
    }

    kapt {
        correctErrorTypes = true
        includeCompileClasspath = false
    }
}

dependencies {
    implementation project(':fastcraft-core')
    implementation project(':fastcraft-bukkit')
}

jar {
    enabled = false
    dependsOn shadowJar
}

shadowJar {
    archiveClassifier.set(null)
    archiveVersion.set(archiveVersion.get().replace('+', '-'))

    dependencies {
        subprojects.each {
            include dependency(it)
        }

        include dependency("org.jetbrains.kotlin:kotlin-stdlib")
        include dependency("org.jetbrains.kotlin:kotlin-stdlib-jdk7")
        include dependency("org.jetbrains.kotlin:kotlin-stdlib-jdk8")
        include dependency("org.jetbrains.kotlinx:kotlinx-serialization-core-jvm")
        include dependency("org.jetbrains.kotlinx:kotlinx-serialization-json-jvm")
        include dependency("com.google.dagger:dagger")
        include dependency("javax.inject:javax.inject")
        include dependency("net.benwoodworth.localeconfig:localeconfig-api")
        include dependency("org.bstats:bstats-bukkit-lite")
    }

    def libPackage = "net.benwoodworth.fastcraft.lib"
    relocate("kotlin", "${libPackage}.kotlin")
    relocate("kotlinx", "${libPackage}.kotlinx")
    relocate("dagger", "${libPackage}.dagger")
    relocate("javax.inject", "${libPackage}.javax.inject")
    relocate("net.benwoodworth.localeconfig", "${libPackage}.localeconfig")
    relocate("org.bstats", "${libPackage}.bstats")

    minimize {
        subprojects.each {
            exclude dependency(it)
        }
    }
}